鱼C论坛

 找回密码
 立即注册
查看: 2666|回复: 0

[学习笔记] X86汇编语言-从实模式到保护模式—笔记(39)-第14章 任务和特权级保护(5)

[复制链接]
发表于 2017-12-9 21:30:04 | 显示全部楼层 |阅读模式

马上注册,结交更多好友,享用更多功能^_^

您需要 登录 才可以下载或查看,没有账号?立即注册

x
本帖最后由 兰陵月 于 2017-12-15 12:21 编辑
  1.          ;代码清单14-1
  2.          ;文件名:c14_core.asm
  3.          ;文件说明:保护模式微型核心程序
  4.          ;创建日期:2011-11-6 18:37

  5.          ;以下常量定义部分。内核的大部分内容都应当固定
  6.          core_code_seg_sel     equ  0x38    ;内核代码段选择子
  7.          core_data_seg_sel     equ  0x30    ;内核数据段选择子
  8.          sys_routine_seg_sel   equ  0x28    ;系统公共例程代码段的选择子
  9.          video_ram_seg_sel     equ  0x20    ;视频显示缓冲区的段选择子
  10.          core_stack_seg_sel    equ  0x18    ;内核堆栈段选择子
  11.          mem_0_4_gb_seg_sel    equ  0x08    ;整个0-4GB内存的段的选择子

  12. ;-------------------------------------------------------------------------------
  13.          ;以下是系统核心的头部,用于加载核心程序
  14.          core_length      dd core_end       ;核心程序总长度#00

  15.          sys_routine_seg  dd section.sys_routine.start
  16.                                             ;系统公用例程段位置#04

  17.          core_data_seg    dd section.core_data.start
  18.                                             ;核心数据段位置#08

  19.          core_code_seg    dd section.core_code.start
  20.                                             ;核心代码段位置#0c


  21.          core_entry       dd start          ;核心代码段入口点#10
  22.                           dw core_code_seg_sel

  23. ;===============================================================================
  24.          [bits 32]
  25. ;===============================================================================
  26. SECTION sys_routine vstart=0                ;系统公共例程代码段
  27. ;-------------------------------------------------------------------------------
  28.          ;字符串显示例程
  29. put_string:                                 ;显示0终止的字符串并移动光标
  30.                                             ;输入:DS:EBX=串地址
  31.          push ecx
  32.   .getc:
  33.          mov cl,[ebx]
  34.          or cl,cl
  35.          jz .exit
  36.          call put_char
  37.          inc ebx
  38.          jmp .getc

  39.   .exit:
  40.          pop ecx
  41.          retf                               ;段间返回

  42. ;-------------------------------------------------------------------------------
  43. put_char:                                   ;在当前光标处显示一个字符,并推进
  44.                                             ;光标。仅用于段内调用
  45.                                             ;输入:CL=字符ASCII码
  46.          pushad

  47.          ;以下取当前光标位置
  48.          mov dx,0x3d4
  49.          mov al,0x0e
  50.          out dx,al
  51.          inc dx                             ;0x3d5
  52.          in al,dx                           ;高字
  53.          mov ah,al

  54.          dec dx                             ;0x3d4
  55.          mov al,0x0f
  56.          out dx,al
  57.          inc dx                             ;0x3d5
  58.          in al,dx                           ;低字
  59.          mov bx,ax                          ;BX=代表光标位置的16位数

  60.          cmp cl,0x0d                        ;回车符?
  61.          jnz .put_0a
  62.          mov ax,bx
  63.          mov bl,80
  64.          div bl
  65.          mul bl
  66.          mov bx,ax
  67.          jmp .set_cursor

  68.   .put_0a:
  69.          cmp cl,0x0a                        ;换行符?
  70.          jnz .put_other
  71.          add bx,80
  72.          jmp .roll_screen

  73.   .put_other:                               ;正常显示字符
  74.          push es
  75.          mov eax,video_ram_seg_sel          ;0xb8000段的选择子
  76.          mov es,eax
  77.          shl bx,1
  78.          mov [es:bx],cl
  79.          pop es

  80.          ;以下将光标位置推进一个字符
  81.          shr bx,1
  82.          inc bx

  83.   .roll_screen:
  84.          cmp bx,2000                        ;光标超出屏幕?滚屏
  85.          jl .set_cursor

  86.          push ds
  87.          push es
  88.          mov eax,video_ram_seg_sel
  89.          mov ds,eax
  90.          mov es,eax
  91.          cld
  92.          mov esi,0xa0                       ;小心!32位模式下movsb/w/d
  93.          mov edi,0x00                       ;使用的是esi/edi/ecx
  94.          mov ecx,1920
  95.          rep movsd
  96.          mov bx,3840                        ;清除屏幕最底一行
  97.          mov ecx,80                         ;32位程序应该使用ECX
  98.   .cls:
  99.          mov word[es:bx],0x0720
  100.          add bx,2
  101.          loop .cls

  102.          pop es
  103.          pop ds

  104.          mov bx,1920

  105.   .set_cursor:
  106.          mov dx,0x3d4
  107.          mov al,0x0e
  108.          out dx,al
  109.          inc dx                             ;0x3d5
  110.          mov al,bh
  111.          out dx,al
  112.          dec dx                             ;0x3d4
  113.          mov al,0x0f
  114.          out dx,al
  115.          inc dx                             ;0x3d5
  116.          mov al,bl
  117.          out dx,al

  118.          popad
  119.          
  120.          ret                                

  121. ;-------------------------------------------------------------------------------
  122. read_hard_disk_0:                           ;从硬盘读取一个逻辑扇区
  123.                                             ;EAX=逻辑扇区号
  124.                                             ;DS:EBX=目标缓冲区地址
  125.                                             ;返回:EBX=EBX+512
  126.          push eax
  127.          push ecx
  128.          push edx
  129.       
  130.          push eax
  131.          
  132.          mov dx,0x1f2
  133.          mov al,1
  134.          out dx,al                          ;读取的扇区数

  135.          inc dx                             ;0x1f3
  136.          pop eax
  137.          out dx,al                          ;LBA地址7~0

  138.          inc dx                             ;0x1f4
  139.          mov cl,8
  140.          shr eax,cl
  141.          out dx,al                          ;LBA地址15~8

  142.          inc dx                             ;0x1f5
  143.          shr eax,cl
  144.          out dx,al                          ;LBA地址23~16

  145.          inc dx                             ;0x1f6
  146.          shr eax,cl
  147.          or al,0xe0                         ;第一硬盘  LBA地址27~24
  148.          out dx,al

  149.          inc dx                             ;0x1f7
  150.          mov al,0x20                        ;读命令
  151.          out dx,al

  152.   .waits:
  153.          in al,dx
  154.          and al,0x88
  155.          cmp al,0x08
  156.          jnz .waits                         ;不忙,且硬盘已准备好数据传输

  157.          mov ecx,256                        ;总共要读取的字数
  158.          mov dx,0x1f0
  159.   .readw:
  160.          in ax,dx
  161.          mov [ebx],ax
  162.          add ebx,2
  163.          loop .readw

  164.          pop edx
  165.          pop ecx
  166.          pop eax
  167.       
  168.          retf                               ;段间返回

  169. ;-------------------------------------------------------------------------------
  170. ;汇编语言程序是极难一次成功,而且调试非常困难。这个例程可以提供帮助
  171. put_hex_dword:                              ;在当前光标处以十六进制形式显示
  172.                                             ;一个双字并推进光标
  173.                                             ;输入:EDX=要转换并显示的数字
  174.                                             ;输出:无
  175.          pushad
  176.          push ds
  177.       
  178.          mov ax,core_data_seg_sel           ;切换到核心数据段
  179.          mov ds,ax
  180.       
  181.          mov ebx,bin_hex                    ;指向核心数据段内的转换表
  182.          mov ecx,8
  183.   .xlt:   
  184.          rol edx,4
  185.          mov eax,edx
  186.          and eax,0x0000000f
  187.          xlat
  188.       
  189.          push ecx
  190.          mov cl,al                           
  191.          call put_char
  192.          pop ecx
  193.       
  194.          loop .xlt
  195.       
  196.          pop ds
  197.          popad
  198.          retf
  199.       
  200. ;-------------------------------------------------------------------------------
  201. allocate_memory:                            ;分配内存
  202.                                             ;输入:ECX=希望分配的字节数
  203.                                             ;输出:ECX=起始线性地址
  204.          push ds
  205.          push eax
  206.          push ebx
  207.       
  208.          mov eax,core_data_seg_sel
  209.          mov ds,eax
  210.       
  211.          mov eax,[ram_alloc]
  212.          add eax,ecx                        ;下一次分配时的起始地址
  213.       
  214.          ;这里应当有检测可用内存数量的指令
  215.          
  216.          mov ecx,[ram_alloc]                ;返回分配的起始地址

  217.          mov ebx,eax
  218.          and ebx,0xfffffffc
  219.          add ebx,4                          ;强制对齐
  220.          test eax,0x00000003                ;下次分配的起始地址最好是4字节对齐
  221.          cmovnz eax,ebx                     ;如果没有对齐,则强制对齐
  222.          mov [ram_alloc],eax                ;下次从该地址分配内存
  223.                                             ;cmovcc指令可以避免控制转移
  224.          pop ebx
  225.          pop eax
  226.          pop ds

  227.          retf

  228. ;-------------------------------------------------------------------------------
  229. set_up_gdt_descriptor:                      ;在GDT内安装一个新的描述符
  230.                                             ;输入:EDX:EAX=描述符
  231.                                             ;输出:CX=描述符的选择子
  232.          push eax
  233.          push ebx
  234.          push edx

  235.          push ds
  236.          push es

  237.          mov ebx,core_data_seg_sel          ;切换到核心数据段
  238.          mov ds,ebx

  239.          sgdt [pgdt]                        ;以便开始处理GDT

  240.          mov ebx,mem_0_4_gb_seg_sel
  241.          mov es,ebx

  242.          movzx ebx,word [pgdt]              ;GDT界限
  243.          inc bx                             ;GDT总字节数,也是下一个描述符偏移
  244.          add ebx,[pgdt+2]                   ;下一个描述符的线性地址

  245.          mov [es:ebx],eax
  246.          mov [es:ebx+4],edx

  247.          add word [pgdt],8                  ;增加一个描述符的大小

  248.          lgdt [pgdt]                        ;对GDT的更改生效

  249.          mov ax,[pgdt]                      ;得到GDT界限值
  250.          xor dx,dx
  251.          mov bx,8
  252.          div bx                             ;除以8,去掉余数
  253.          mov cx,ax
  254.          shl cx,3                           ;将索引号移到正确位置

  255.          pop es
  256.          pop ds

  257.          pop edx
  258.          pop ebx
  259.          pop eax

  260.          retf
  261. ;-------------------------------------------------------------------------------
  262. make_seg_descriptor:                        ;构造存储器和系统的段描述符
  263.                                             ;输入:EAX=线性基地址
  264.                                             ;      EBX=段界限
  265.                                             ;      ECX=属性。各属性位都在原始
  266.                                             ;          位置,无关的位清零
  267.                                             ;返回:EDX:EAX=描述符
  268.          mov edx,eax
  269.          shl eax,16
  270.          or ax,bx                           ;描述符前32位(EAX)构造完毕

  271.          and edx,0xffff0000                 ;清除基地址中无关的位
  272.          rol edx,8
  273.          bswap edx                          ;装配基址的31~24和23~16  (80486+)

  274.          xor bx,bx
  275.          or edx,ebx                         ;装配段界限的高4位

  276.          or edx,ecx                         ;装配属性

  277.          retf

  278. ;-------------------------------------------------------------------------------
  279. make_gate_descriptor:                       ;构造门的描述符(调用门等)
  280.                                             ;输入:EAX=门代码在段内偏移地址
  281.                                             ;       BX=门代码所在段的选择子
  282.                                             ;       CX=段类型及属性等(各属
  283.                                             ;          性位都在原始位置)
  284.                                             ;返回:EDX:EAX=完整的描述符
  285.          push ebx
  286.          push ecx
  287.       
  288.          mov edx,eax
  289.          and edx,0xffff0000                 ;得到偏移地址高16位
  290.          or dx,cx                           ;组装属性部分到EDX
  291.       
  292.          and eax,0x0000ffff                 ;得到偏移地址低16位
  293.          shl ebx,16                          
  294.          or eax,ebx                         ;组装段选择子部分
  295.       
  296.          pop ecx
  297.          pop ebx
  298.       
  299.          retf                                   
  300.                              
  301. sys_routine_end:

  302. ;===============================================================================
  303. SECTION core_data vstart=0                  ;系统核心的数据段
  304. ;-------------------------------------------------------------------------------
  305.          pgdt             dw  0             ;用于设置和修改GDT
  306.                           dd  0

  307.          ram_alloc        dd  0x00100000    ;下次分配内存时的起始地址

  308.          ;符号地址检索表
  309.          salt:
  310.          salt_1           db  '@PrintString'
  311.                      times 256-($-salt_1) db 0
  312.                           dd  put_string
  313.                           dw  sys_routine_seg_sel

  314.          salt_2           db  '@ReadDiskData'
  315.                      times 256-($-salt_2) db 0
  316.                           dd  read_hard_disk_0
  317.                           dw  sys_routine_seg_sel

  318.          salt_3           db  '@PrintDwordAsHexString'
  319.                      times 256-($-salt_3) db 0
  320.                           dd  put_hex_dword
  321.                           dw  sys_routine_seg_sel

  322.          salt_4           db  '@TerminateProgram'
  323.                      times 256-($-salt_4) db 0
  324.                           dd  return_point
  325.                           dw  core_code_seg_sel

  326.          salt_item_len   equ $-salt_4
  327.          salt_items      equ ($-salt)/salt_item_len

  328.          message_1        db  '  If you seen this message,that means we '
  329.                           db  'are now in protect mode,and the system '
  330.                           db  'core is loaded,and the video display '
  331.                           db  'routine works perfectly.',0x0d,0x0a,0

  332.          message_2        db  '  System wide CALL-GATE mounted.',0x0d,0x0a,0
  333.          
  334.          message_3        db  0x0d,0x0a,'  Loading user program...',0
  335.          
  336.          do_status        db  'Done.',0x0d,0x0a,0
  337.          
  338.          message_6        db  0x0d,0x0a,0x0d,0x0a,0x0d,0x0a
  339.                           db  '  User program terminated,control returned.',0

  340.          bin_hex          db '0123456789ABCDEF'
  341.                                             ;put_hex_dword子过程用的查找表

  342.          core_buf   times 2048 db 0         ;内核用的缓冲区

  343.          esp_pointer      dd 0              ;内核用来临时保存自己的栈指针     

  344.          cpu_brnd0        db 0x0d,0x0a,'  ',0
  345.          cpu_brand  times 52 db 0
  346.          cpu_brnd1        db 0x0d,0x0a,0x0d,0x0a,0

  347.          ;任务控制块链
  348.          tcb_chain        dd  0

  349. core_data_end:
  350.                
  351. ;===============================================================================
  352. SECTION core_code vstart=0
  353. ;-------------------------------------------------------------------------------
  354. fill_descriptor_in_ldt:                     ;在LDT内安装一个新的描述符
  355.                                             ;输入:EDX:EAX=描述符
  356.                                             ;          EBX=TCB基地址
  357.                                             ;输出:CX=描述符的选择子
  358.          push eax
  359.          push edx
  360.          push edi
  361.          push ds

  362.          mov ecx,mem_0_4_gb_seg_sel
  363.          mov ds,ecx

  364.          mov edi,[ebx+0x0c]                 ;获得LDT基地址
  365.          
  366.          xor ecx,ecx
  367.          mov cx,[ebx+0x0a]                  ;获得LDT界限
  368.          inc cx                             ;LDT的总字节数,即新描述符偏移地址
  369.          
  370.          mov [edi+ecx+0x00],eax
  371.          mov [edi+ecx+0x04],edx             ;安装描述符

  372.          add cx,8                           
  373.          dec cx                             ;得到新的LDT界限值

  374.          mov [ebx+0x0a],cx                  ;更新LDT界限值到TCB

  375.          mov ax,cx
  376.          xor dx,dx
  377.          mov cx,8
  378.          div cx
  379.          
  380.          mov cx,ax
  381.          shl cx,3                           ;左移3位,并且
  382.          or cx,0000_0000_0000_0100B         ;使TI位=1,指向LDT,最后使RPL=00

  383.          pop ds
  384.          pop edi
  385.          pop edx
  386.          pop eax
  387.      
  388.          ret
  389.       
  390. ;-------------------------------------------------------------------------------
  391. load_relocate_program:                      ;加载并重定位用户程序
  392.                                             ;输入: PUSH 逻辑扇区号
  393.                                             ;      PUSH 任务控制块基地址
  394.                                             ;输出:无
  395.          pushad
  396.       
  397.          push ds
  398.          push es
  399.       
  400.          mov ebp,esp                        ;为访问通过堆栈传递的参数做准备
  401.       
  402.          mov ecx,mem_0_4_gb_seg_sel
  403.          mov es,ecx
  404.       
  405.          mov esi,[ebp+11*4]                 ;从堆栈中取得TCB的基地址

  406.          ;以下申请创建LDT所需要的内存
  407.          mov ecx,160                        ;允许安装20个LDT描述符
  408.          call sys_routine_seg_sel:allocate_memory
  409.          mov [es:esi+0x0c],ecx              ;登记LDT基地址到TCB中
  410.          mov word [es:esi+0x0a],0xffff      ;登记LDT初始的界限到TCB中

  411.          ;以下开始加载用户程序
  412.          mov eax,core_data_seg_sel
  413.          mov ds,eax                         ;切换DS到内核数据段
  414.       
  415.          mov eax,[ebp+12*4]                 ;从堆栈中取出用户程序起始扇区号
  416.          mov ebx,core_buf                   ;读取程序头部数据     
  417.          call sys_routine_seg_sel:read_hard_disk_0

  418.          ;以下判断整个程序有多大
  419.          mov eax,[core_buf]                 ;程序尺寸
  420.          mov ebx,eax
  421.          and ebx,0xfffffe00                 ;使之512字节对齐(能被512整除的数低
  422.          add ebx,512                        ;9位都为0
  423.          test eax,0x000001ff                ;程序的大小正好是512的倍数吗?
  424.          cmovnz eax,ebx                     ;不是。使用凑整的结果
  425.       
  426.          mov ecx,eax                        ;实际需要申请的内存数量
  427.          call sys_routine_seg_sel:allocate_memory
  428.          mov [es:esi+0x06],ecx              ;登记程序加载基地址到TCB中
  429.       
  430.          mov ebx,ecx                        ;ebx -> 申请到的内存首地址
  431.          xor edx,edx
  432.          mov ecx,512
  433.          div ecx
  434.          mov ecx,eax                        ;总扇区数
  435.       
  436.          mov eax,mem_0_4_gb_seg_sel         ;切换DS到0-4GB的段
  437.          mov ds,eax

  438.          mov eax,[ebp+12*4]                 ;起始扇区号
  439.   .b1:
  440.          call sys_routine_seg_sel:read_hard_disk_0
  441.          inc eax
  442.          loop .b1                           ;循环读,直到读完整个用户程序

  443.          mov edi,[es:esi+0x06]              ;获得程序加载基地址

  444.          ;建立程序头部段描述符
  445.          mov eax,edi                        ;程序头部起始线性地址
  446.          mov ebx,[edi+0x04]                 ;段长度
  447.          dec ebx                            ;段界限
  448.          mov ecx,0x0040f200                 ;字节粒度的数据段描述符,特权级3
  449.          call sys_routine_seg_sel:make_seg_descriptor
  450.       
  451.          ;安装头部段描述符到LDT中
  452.          mov ebx,esi                        ;TCB的基地址
  453.          call fill_descriptor_in_ldt

  454.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  455.          mov [es:esi+0x44],cx               ;登记程序头部段选择子到TCB
  456.          mov [edi+0x04],cx                  ;和头部内
  457.       
  458.          ;建立程序代码段描述符
  459.          mov eax,edi
  460.          add eax,[edi+0x14]                 ;代码起始线性地址
  461.          mov ebx,[edi+0x18]                 ;段长度
  462.          dec ebx                            ;段界限
  463.          mov ecx,0x0040f800                 ;字节粒度的代码段描述符,特权级3
  464.          call sys_routine_seg_sel:make_seg_descriptor
  465.          mov ebx,esi                        ;TCB的基地址
  466.          call fill_descriptor_in_ldt
  467.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  468.          mov [edi+0x14],cx                  ;登记代码段选择子到头部

  469.          ;建立程序数据段描述符
  470.          mov eax,edi
  471.          add eax,[edi+0x1c]                 ;数据段起始线性地址
  472.          mov ebx,[edi+0x20]                 ;段长度
  473.          dec ebx                            ;段界限
  474.          mov ecx,0x0040f200                 ;字节粒度的数据段描述符,特权级3
  475.          call sys_routine_seg_sel:make_seg_descriptor
  476.          mov ebx,esi                        ;TCB的基地址
  477.          call fill_descriptor_in_ldt
  478.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  479.          mov [edi+0x1c],cx                  ;登记数据段选择子到头部

  480.          ;建立程序堆栈段描述符
  481.          mov ecx,[edi+0x0c]                 ;4KB的倍率
  482.          mov ebx,0x000fffff
  483.          sub ebx,ecx                        ;得到段界限
  484.          mov eax,4096                        
  485.          mul ecx                        
  486.          mov ecx,eax                        ;准备为堆栈分配内存
  487.          call sys_routine_seg_sel:allocate_memory
  488.          add eax,ecx                        ;得到堆栈的高端物理地址
  489.          mov ecx,0x00c0f600                 ;字节粒度的堆栈段描述符,特权级3
  490.          call sys_routine_seg_sel:make_seg_descriptor
  491.          mov ebx,esi                        ;TCB的基地址
  492.          call fill_descriptor_in_ldt
  493.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  494.          mov [edi+0x08],cx                  ;登记堆栈段选择子到头部

  495.          ;重定位SALT
  496.          mov eax,mem_0_4_gb_seg_sel         ;这里和前一章不同,头部段描述符
  497.          mov es,eax                         ;已安装,但还没有生效,故只能通
  498.                                             ;过4GB段访问用户程序头部         
  499.          mov eax,core_data_seg_sel
  500.          mov ds,eax
  501.       
  502.          cld

  503.          mov ecx,[es:edi+0x24]              ;U-SALT条目数(通过访问4GB段取得)
  504.          add edi,0x28                       ;U-SALT在4GB段内的偏移
  505.   .b2:
  506.          push ecx
  507.          push edi
  508.       
  509.          mov ecx,salt_items
  510.          mov esi,salt
  511.   .b3:
  512.          push edi
  513.          push esi
  514.          push ecx

  515.          mov ecx,64                         ;检索表中,每条目的比较次数
  516.          repe cmpsd                         ;每次比较4字节
  517.          jnz .b4
  518.          mov eax,[esi]                      ;若匹配,则esi恰好指向其后的地址
  519.          mov [es:edi-256],eax               ;将字符串改写成偏移地址
  520.          mov ax,[esi+4]
  521.          or ax,0000000000000011B            ;以用户程序自己的特权级使用调用门
  522.                                             ;故RPL=3
  523.          mov [es:edi-252],ax                ;回填调用门选择子
  524.   .b4:
  525.       
  526.          pop ecx
  527.          pop esi
  528.          add esi,salt_item_len
  529.          pop edi                            ;从头比较
  530.          loop .b3
  531.       
  532.          pop edi
  533.          add edi,256
  534.          pop ecx
  535.          loop .b2

  536.          mov esi,[ebp+11*4]                 ;从堆栈中取得TCB的基地址

  537.          ;创建0特权级堆栈
  538.          mov ecx,4096
  539.          mov eax,ecx                        ;为生成堆栈高端地址做准备
  540.          mov [es:esi+0x1a],ecx
  541.          shr dword [es:esi+0x1a],12         ;登记0特权级堆栈尺寸到TCB
  542.          call sys_routine_seg_sel:allocate_memory
  543.          add eax,ecx                        ;堆栈必须使用高端地址为基地址
  544.          mov [es:esi+0x1e],eax              ;登记0特权级堆栈基地址到TCB
  545.          mov ebx,0xffffe                    ;段长度(界限)
  546.          mov ecx,0x00c09600                 ;4KB粒度,读写,特权级0
  547.          call sys_routine_seg_sel:make_seg_descriptor
  548.          mov ebx,esi                        ;TCB的基地址
  549.          call fill_descriptor_in_ldt
  550.          ;or cx,0000_0000_0000_0000          ;设置选择子的特权级为0
  551.          mov [es:esi+0x22],cx               ;登记0特权级堆栈选择子到TCB
  552.          mov dword [es:esi+0x24],0          ;登记0特权级堆栈初始ESP到TCB
  553.       
  554.          ;创建1特权级堆栈
  555.          mov ecx,4096
  556.          mov eax,ecx                        ;为生成堆栈高端地址做准备
  557.          mov [es:esi+0x28],ecx
  558.          shr [es:esi+0x28],12               ;登记1特权级堆栈尺寸到TCB
  559.          call sys_routine_seg_sel:allocate_memory
  560.          add eax,ecx                        ;堆栈必须使用高端地址为基地址
  561.          mov [es:esi+0x2c],eax              ;登记1特权级堆栈基地址到TCB
  562.          mov ebx,0xffffe                    ;段长度(界限)
  563.          mov ecx,0x00c0b600                 ;4KB粒度,读写,特权级1
  564.          call sys_routine_seg_sel:make_seg_descriptor
  565.          mov ebx,esi                        ;TCB的基地址
  566.          call fill_descriptor_in_ldt
  567.          or cx,0000_0000_0000_0001          ;设置选择子的特权级为1
  568.          mov [es:esi+0x30],cx               ;登记1特权级堆栈选择子到TCB
  569.          mov dword [es:esi+0x32],0          ;登记1特权级堆栈初始ESP到TCB

  570.          ;创建2特权级堆栈
  571.          mov ecx,4096
  572.          mov eax,ecx                        ;为生成堆栈高端地址做准备
  573.          mov [es:esi+0x36],ecx
  574.          shr [es:esi+0x36],12               ;登记2特权级堆栈尺寸到TCB
  575.          call sys_routine_seg_sel:allocate_memory
  576.          add eax,ecx                        ;堆栈必须使用高端地址为基地址
  577.          mov [es:esi+0x3a],ecx              ;登记2特权级堆栈基地址到TCB
  578.          mov ebx,0xffffe                    ;段长度(界限)
  579.          mov ecx,0x00c0d600                 ;4KB粒度,读写,特权级2
  580.          call sys_routine_seg_sel:make_seg_descriptor
  581.          mov ebx,esi                        ;TCB的基地址
  582.          call fill_descriptor_in_ldt
  583.          or cx,0000_0000_0000_0010          ;设置选择子的特权级为2
  584.          mov [es:esi+0x3e],cx               ;登记2特权级堆栈选择子到TCB
  585.          mov dword [es:esi+0x40],0          ;登记2特权级堆栈初始ESP到TCB
  586.       
  587.          ;在GDT中登记LDT描述符
  588.          mov eax,[es:esi+0x0c]              ;LDT的起始线性地址
  589.          movzx ebx,word [es:esi+0x0a]       ;LDT段界限
  590.          mov ecx,0x00408200                 ;LDT描述符,特权级0
  591.          call sys_routine_seg_sel:make_seg_descriptor
  592.          call sys_routine_seg_sel:set_up_gdt_descriptor
  593.          mov [es:esi+0x10],cx               ;登记LDT选择子到TCB中
  594.       
  595.          ;创建用户程序的TSS
  596.          mov ecx,104                        ;tss的基本尺寸
  597.          mov [es:esi+0x12],cx              
  598.          dec word [es:esi+0x12]             ;登记TSS界限值到TCB
  599.          call sys_routine_seg_sel:allocate_memory
  600.          mov [es:esi+0x14],ecx              ;登记TSS基地址到TCB
  601.       
  602.          ;登记基本的TSS表格内容
  603.          mov word [es:ecx+0],0              ;反向链=0
  604.       
  605.          mov edx,[es:esi+0x24]              ;登记0特权级堆栈初始ESP
  606.          mov [es:ecx+4],edx                 ;到TSS中
  607.       
  608.          mov dx,[es:esi+0x22]               ;登记0特权级堆栈段选择子
  609.          mov [es:ecx+8],dx                  ;到TSS中
  610.       
  611.          mov edx,[es:esi+0x32]              ;登记1特权级堆栈初始ESP
  612.          mov [es:ecx+12],edx                ;到TSS中

  613.          mov dx,[es:esi+0x30]               ;登记1特权级堆栈段选择子
  614.          mov [es:ecx+16],dx                 ;到TSS中

  615.          mov edx,[es:esi+0x40]              ;登记2特权级堆栈初始ESP
  616.          mov [es:ecx+20],edx                ;到TSS中

  617.          mov dx,[es:esi+0x3e]               ;登记2特权级堆栈段选择子
  618.          mov [es:ecx+24],dx                 ;到TSS中

  619.          mov dx,[es:esi+0x10]               ;登记任务的LDT选择子
  620.          mov [es:ecx+96],dx                 ;到TSS中
  621.       
  622.          mov dx,[es:esi+0x12]               ;登记任务的I/O位图偏移
  623.          mov [es:ecx+102],dx                ;到TSS中
  624.       
  625.          mov word [es:ecx+100],0            ;T=0
  626.       
  627.          ;在GDT中登记TSS描述符
  628.          mov eax,[es:esi+0x14]              ;TSS的起始线性地址
  629.          movzx ebx,word [es:esi+0x12]       ;段长度(界限)
  630.          mov ecx,0x00408900                 ;TSS描述符,特权级0
  631.          call sys_routine_seg_sel:make_seg_descriptor
  632.          call sys_routine_seg_sel:set_up_gdt_descriptor
  633.          mov [es:esi+0x18],cx               ;登记TSS选择子到TCB

  634.          pop es                             ;恢复到调用此过程前的es段
  635.          pop ds                             ;恢复到调用此过程前的ds段
  636.       
  637.          popad
  638.       
  639.          ret 8                              ;丢弃调用本过程前压入的参数
  640.       
  641. ;-------------------------------------------------------------------------------
  642. append_to_tcb_link:                         ;在TCB链上追加任务控制块
  643.                                             ;输入:ECX=TCB线性基地址
  644.          push eax
  645.          push edx
  646.          push ds
  647.          push es
  648.          
  649.          mov eax,core_data_seg_sel          ;令DS指向内核数据段
  650.          mov ds,eax
  651.          mov eax,mem_0_4_gb_seg_sel         ;令ES指向0..4GB段
  652.          mov es,eax
  653.          
  654.          mov dword [es: ecx+0x00],0         ;当前TCB指针域清零,以指示这是最
  655.                                             ;后一个TCB
  656.                                              
  657.          mov eax,[tcb_chain]                ;TCB表头指针
  658.          or eax,eax                         ;链表为空?
  659.          jz .notcb
  660.          
  661.   .searc:
  662.          mov edx,eax
  663.          mov eax,[es: edx+0x00]
  664.          or eax,eax               
  665.          jnz .searc
  666.          
  667.          mov [es: edx+0x00],ecx
  668.          jmp .retpc
  669.          
  670.   .notcb:      
  671.          mov [tcb_chain],ecx                ;若为空表,直接令表头指针指向TCB
  672.          
  673.   .retpc:
  674.          pop es
  675.          pop ds
  676.          pop edx
  677.          pop eax
  678.          
  679.          ret
  680.          
  681. ;-------------------------------------------------------------------------------
  682. start:
  683.          mov ecx,core_data_seg_sel          ;使ds指向核心数据段
  684.          mov ds,ecx

  685.          mov ebx,message_1                    
  686.          call sys_routine_seg_sel:put_string
  687.                                          
  688.          ;显示处理器品牌信息
  689.          mov eax,0x80000002
  690.          cpuid
  691.          mov [cpu_brand + 0x00],eax
  692.          mov [cpu_brand + 0x04],ebx
  693.          mov [cpu_brand + 0x08],ecx
  694.          mov [cpu_brand + 0x0c],edx
  695.       
  696.          mov eax,0x80000003
  697.          cpuid
  698.          mov [cpu_brand + 0x10],eax
  699.          mov [cpu_brand + 0x14],ebx
  700.          mov [cpu_brand + 0x18],ecx
  701.          mov [cpu_brand + 0x1c],edx

  702.          mov eax,0x80000004
  703.          cpuid
  704.          mov [cpu_brand + 0x20],eax
  705.          mov [cpu_brand + 0x24],ebx
  706.          mov [cpu_brand + 0x28],ecx
  707.          mov [cpu_brand + 0x2c],edx

  708.          mov ebx,cpu_brnd0                  ;显示处理器品牌信息
  709.          call sys_routine_seg_sel:put_string
  710.          mov ebx,cpu_brand
  711.          call sys_routine_seg_sel:put_string
  712.          mov ebx,cpu_brnd1
  713.          call sys_routine_seg_sel:put_string

  714.          ;以下开始安装为整个系统服务的调用门。特权级之间的控制转移必须使用门
  715.          mov edi,salt                       ;C-SALT表的起始位置
  716.          mov ecx,salt_items                 ;C-SALT表的条目数量
  717.   .b3:
  718.          push ecx   
  719.          mov eax,[edi+256]                  ;该条目入口点的32位偏移地址
  720.          mov bx,[edi+260]                   ;该条目入口点的段选择子
  721.          mov cx,1_11_0_1100_000_00000B      ;特权级3的调用门(3以上的特权级才
  722.                                             ;允许访问),0个参数(因为用寄存器
  723.                                             ;传递参数,而没有用栈)
  724.          call sys_routine_seg_sel:make_gate_descriptor
  725.          call sys_routine_seg_sel:set_up_gdt_descriptor
  726.          mov [edi+260],cx                   ;将返回的门描述符选择子回填
  727.          add edi,salt_item_len              ;指向下一个C-SALT条目
  728.          pop ecx
  729.          loop .b3

  730.          ;对门进行测试
  731.          mov ebx,message_2
  732.          call far [salt_1+256]              ;通过门显示信息(偏移量将被忽略)
  733.       
  734.          mov ebx,message_3                    
  735.          call sys_routine_seg_sel:put_string ;在内核中调用例程不需要通过门
  736.       
  737.          ;创建任务控制块。这不是处理器的要求,而是我们自己为了方便而设立的
  738.          mov ecx,0x46
  739.          call sys_routine_seg_sel:allocate_memory
  740.          call append_to_tcb_link            ;将任务控制块追加到TCB链表
  741.       
  742.          push dword 50                      ;用户程序位于逻辑50扇区
  743.          push ecx                           ;压入任务控制块起始线性地址
  744.       
  745.          call load_relocate_program
  746.       
  747.          mov ebx,do_status
  748.          call sys_routine_seg_sel:put_string
  749.       
  750.          mov eax,mem_0_4_gb_seg_sel
  751.          mov ds,eax
  752.       
  753.          ltr [ecx+0x18]                     ;加载任务状态段
  754.          lldt [ecx+0x10]                    ;加载LDT
  755.       
  756.          mov eax,[ecx+0x44]
  757.          mov ds,eax                         ;切换到用户程序头部段

  758.          ;以下假装是从调用门返回。摹仿处理器压入返回参数
  759.          push dword [0x08]                  ;调用前的堆栈段选择子
  760.          push dword 0                       ;调用前的esp

  761.          push dword [0x14]                  ;调用前的代码段选择子
  762.          push dword [0x10]                  ;调用前的eip
  763.       
  764.          retf

  765. return_point:                               ;用户程序返回点
  766.          mov eax,core_data_seg_sel          ;因为c14.asm是以JMP的方式使用调
  767.          mov ds,eax                         ;用门@TerminateProgram,回到这
  768.                                             ;里时,特权级为3,会导致异常。
  769.          mov ebx,message_6
  770.          call sys_routine_seg_sel:put_string

  771.          hlt
  772.             
  773. core_code_end:

  774. ;-------------------------------------------------------------------------------
  775. SECTION core_trail
  776. ;-------------------------------------------------------------------------------
  777. core_end:
复制代码

本帖被以下淘专辑推荐:

想知道小甲鱼最近在做啥?请访问 -> ilovefishc.com
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

小黑屋|手机版|Archiver|鱼C工作室 ( 粤ICP备18085999号-1 | 粤公网安备 44051102000585号)

GMT+8, 2024-3-29 22:54

Powered by Discuz! X3.4

© 2001-2023 Discuz! Team.

快速回复 返回顶部 返回列表